WebGUI 8 Apps

Doug Bell

Plain Black Corp | WebGUI

WebGUI

• A Perl Web Content Management System
• First public release: 0.9 August 2001
• Most recent stable series: 7.0 July 2006
• 8.x development started October 2009
• 8.x alpha: June 2011!
• 2000 commits

WebGUI 8

• InnoDB
• PSGI/Plack
• Upgrade System
• CHI Cache
• Moose-based Assets
• Admin Interface
• JSON Services
• Asset Helpers
• FormBuilder

WebGUI 8

• Asset Dispatch
• WebGUI Command
• New WRE
• Nginx
• Template Toolkit integration
• Facebook and Twitter login

Hello, World!

package WebGUI::Asset::HelloWorld;

use Moose;
use WebGUI::Definition::Asset;
extends 'WebGUI::Asset';

define 'assetName' => 'Hello World';

sub www_view {
    my ( $self ) = @_;
    my $resp = $self->session->response;
    $resp->content_type('text/plain');
    return "Hello, World!\n";
}

1;

Moose Definition

use WebGUI::Definition::Asset;
define 'assetName' => 'Hello World';

• define 'tableName' => 'HelloWorld';
  

• property 'greeting' => (
      tab         => 'properties',
      fieldType   => 'text',
      label       => 'Greeting',
      default     => 'Hello',
  );
  $self->greeting;
  $self->greeting( 'Bonjour' );
  

• has 'something' => ( is => 'rw', isa => 'Array', );
  

Plack

$session->request->content_type( 'text/html' );

• WebGUI::Session::Request isa Plack::Request
• WebGUI::Session::Response isa Plack::Response
• WebGUI isa Plack::Component
• Session is created by WebGUI::Middleware::Session isa Plack::Middleware
• Uploads are handled by WebGUI::Middleware::WGAccess
• Debug plugins for MySQL queries and Asset Performance

Installing Asset

// etc/site.conf
{
    "assets" : {
        "WebGUI::Asset::HelloWorld" : {
            "category" : "basic"
        },
    ...
    }
}

Starting WebGUI

# plackup

• Run from WebGUI directory (/data/WebGUI)
• app.psgi is implied

Schema Manager

• You have a DBIC Schema
• You want to manage it in WebGUI
• WebGUI::Asset::Wobject::SchemaManager

Schema Manager Wobject

package WebGUI::Asset::Wobject::SchemaManager;
use Moose;
use WebGUI::Definition::Asset;
extends 'WebGUI::Asset::Wobject';
define 'assetName' => 'Schema Manager';
use My::Schema;
has 'schema' => (
    is      => 'ro',
    lazy    => 1,
    default => sub {
        my $self = $_[0];
        My::Schema->connect(
            sub{ $self->session->db->dbh },
            { unsafe => 1 } 
        );
    },
);

Schema Manager Wobject (cont)

has 'resultClass' => (
    is      => 'ro',
    default => 'My::Schema::Result::Employee',
);

has 'rs' => (
    is      => 'ro',
    lazy    => 1,
    default => sub {
        $_[0]->schema->resultset( $_[0]->resultClass )
    },
);

My::Schema

package My::Schema;
use base 'DBIx::Class::Schema';
__PACKAGE__->load_namespaces();

package My::Schema::Result::Employee;
use base 'DBIx::Class::Core';
__PACKAGE__->table('employee');
__PACKAGE__->add_columns(qw/ id name salary notes /);
__PACKAGE__->set_primary_key('id');

Some Rows

mysql> select * from employee;
+----+--------------+-------------------+--------------------------------------+
| id | name         | salary            | notes                                |
+----+--------------+-------------------+--------------------------------------+
| 1  | Doug Bell    | A pittance        | Barely worth the damage he causes    | 
| 2  | Chris Hanson | Nothing           | Knows and uses VB.                   | 
| 3  | Graham Knop  | Less than nothing | Knows and uses VB. Doesn't enjoy it. | 
+----+--------------+-------------------+--------------------------------------+
3 rows in set (0.00 sec)

A Template

[% FOREACH row IN rows %]
([% row.id %]) [% row.name %] makes [% row.salary %]<br/>
[% row.notes %]<br/>
[% END %]

View the Rows

package WebGUI::Asset::Wobject::SchemaManager;
# ...
sub www_view {
    my ( $self ) = @_;
    my $session = $self->session;
    my $rs = $self->rs;
    my $template
        = WebGUI::Asset->newById( $session, 'TMPL_ID' );
    $template->setParam( 
        rows => [ 
            map { { $_->get_columns } } $rs->all 
        ] );
    return $template;
}

The Output

Templates

• Return a template from a www_method
• Edit that template in a subclass
• Call a macro from Template Toolkit

  [% USE Macro %]
  [% Macro.AssetProxy( 'ASSET_ID' ) %]

• Include an asset inside a TT template

  [% INCLUDE template:/template/url %]
  [% INSERT asset:ASSET_ID %]

Templates (cont)

• Configure TT directly from the config file

  # etc/site.conf
  {
      "template" : {
          "INCLUDE_PATH" : "/data/WebGUI/tmpl",
          "PLUGIN_BASE" : "My::Template::Plugin"
      }
  }

• Downgrade variables HTML::Template can't handle

  { foo => { bar => "baz" }

  { "foo.bar" => "baz" }

  Deletes objects!

Edit Row Form

use WebGUI::FormBuilder;
sub getRowForm {
    my ( $self, $row ) = @_;
    my $fb = WebGUI::FormBuilder->new( $self->session );
    $fb->addField( "ReadOnly",
        name        => 'id',
        label       => 'ID',
        value       => $row ? $row->id
                    : $self->session->id->generate,
    );
    $fb->addField( "Text",
        name        => 'name',
        label       => 'Name',
        value       => $row ? $row->name : '',
    );

Edit Row Form (cont)

    $fb->addField( "Text",
        name        => 'salary',
        label       => 'Salary',
        value       => $row ? $row->salary : '',
    );
    $fb->addField( "Textarea",
        name        => 'notes',
        label       => 'Notes',
        value       => $row ? $row->notes : '',
    );
    return $fb;
}

FormBuilder

• Introspective Forms

  $fb->getField( "notes" )
     ->set( "label" => "Secret!" );

• Forms as Template Variables

  $template->setParam( %{ $fb->toTemplateVars } );

• Process the Form

  my $values = $fb->process;

• Display Validation Errors

  if ( $fb->errors ) { return; }

Edit Row Page

sub www_editRow {
    my ( $self ) = @_;
    my $ses = $self->session;

    my $row;
    if ( my $id = $ses->request->param('id') ) {
        $row = $self->rs->find({ id => $id });
    }

    my $fb = $self->getRowForm( $row );
    $fb->addField( 'Hidden', 
        name => 'func', value => 'editRowSave',
    );
    $fb->addField( 'Submit', name => 'Save' );
    return $fb->toHtml;
}

Save Row Page

sub www_editRowSave {
    my ( $self ) = @_;
    my $req = $self->session->request;

    my $values = $self->getRowForm->process;
    my $row = $self->rs->update_or_create( $values );

    $self->session->response->setRedirect( 
        $self->getUrl
    );
    return;
}

Results as JSON

override dispatch => sub {
    my ( $self, $frag ) = @_;
    if ( $frag eq '.json' ) {
        return JSON->new->encode(
            [
                map { { $_->get_columns } } 
                $self->rs->all 
            ]
        );
    }
    super();
};

Dispatch

• Override default method dispatch
• Do ANYTHING!
• Create services
• Copy Catalyst, Mojo, Dancer, ...
• Asset controls entire URL trees
  • ASSET_URL/subpage
  • ASSET_URL.ext
  • ASSET_URL/subpage/subsubpage.ext

Dispatch Output

[ {
    "notes":"Knows and uses VB. Doesn't enjoy it.",
    "name":"Graham Knop",
    "id":"3",
    "salary":"Less than nothing"
}, {
    "notes":"Knows and users VB",
    "name":"Chris Hanson",
    "id":"2",
    "salary":"Nothing"
},{
    "notes":"Barely worth the damage he causes.",
    "name":"Doug Bell",
    "id":"1",
    "salary":"A pittance"
} ]

Demo!

Broken in lots of ways!

Future Development

• Moving Core Templates to Template Toolkit
• More Rapid Application Development
• CPAN
• More Performance Improvement

Questions

• Slides: http://preaction.github.com/WebGUI/8-apps.html
• Code: http://preaction.github.com/WebGUI/8-apps.tar.gz

Slides are licensed under a CC-BY-SA 3.0 license.

Code is licensed under the Artistic License or GNU GPL v1.0 or later, at your discretion (the same terms as Perl 5 itself).