Testing with PSGI

Doug Bell

Plain Black Corp | WebGUI

What is PSGI?

• Perl Service Gateway Interface
• Perfect Server of Great Ideas
• Perl's answer to WSGI and Rack
• Decouples your web app from the server
• -- in a Perl way

Basic PSGI

# from PSGI.pod
my $app = sub {
      my $env = shift;
      return [
          '200',
          [ 'Content-Type' => 'text/plain' ],
          [ "Hello World" ], # or IO::Handle-like object
      ];
  };

• A Perl code reference
• Accepts a Perl hash reference of environment variables
• Returns a Perl datastructure

Testing with PSGI

• Run the coderef
• Give the right environment variables
• Parse output

Run a PSGI app

use HTTP::Message::PSGI;
use HTTP::Request;
use HTTP::Response;
use MyApp; # is a Plack::Component

my $app = MyApp->to_app;

my $request = HTTP::Request->new;

my $output = $app->( $request->to_psgi );

my $response = HTTP::Response->from_psgi( $output );

Using T::W::M::PSGI

• Test::WWW::Mechanize::PSGI

use Test::More;
use Test::WWW::Mechanize::PSGI;
use MyApp;
my $mech = Test::WWW::Mechanize::PSGI->new( 
                app => MyApp->to_app, );
$mech->get_ok( '/' );
done_testing;

A Guestbook

• The Web 0.0 Killer App
• Hilariously contrived example
• Post a comment to a web site
• Read posted comments

The App Class

package MyApp;
use Moose;
use Template::Simple;
use Plack::Request;
use Plack::Response;
extends 'Plack::Component';

has posts => (
    is      => 'rw',
    lazy    => 1,
    default => sub { [] },
);

The Template

has tmpl => (
    is      => 'ro', lazy => 1,
    default => sub {
        Template::Simple->new(
            templates => {
                view => <<'ENDTMPL',
<form method="POST"><label>Name:<input name="name"/></label>
<label>Comment:<textarea name="text"></textarea></label>
</form>
[% START posts %]
<p>[% name %] -- [% text %]</p>
[% END posts %]
ENDTMPL
            },
        );
    }
);

The View Method

sub call {
    my ( $self, $env ) = @_;

    my $req = Plack::Request->new( $env );
    if ( $req->method eq 'POST' ) {
        $self->add_post( $req->parameters );
    }

    my $res = Plack::Response->new(200);
    $res->content_type('text/html');
    $res->body( $self->posts_html );
    return $res->finalize;
}

The Posts

Add a Post

sub add_post {
    my ( $self, $row ) = @_;
    push @{$self->posts}, $row;
}

Show the Posts

sub posts_html {
    my ( $self ) = @_;
    my $output = $self->tmpl->render( 'view', $posts );
    return ${ $output };
}

Test the Whole Thing

use Test::More;
use Test::WWW::Mechanize::PSGI;
use MyApp;
my $mech = Test::WWW::Mechanize::PSGI->new( 
    app => MyApp->new->to_app,
);

Test the Form

$mech->get_ok( '/', 'get the form' );
$mech->submit_form_ok(
    {
        fields  => {
            name    => 'Scrappy Doo',
            text    => 'Puppy power!',
        },
    }
    "Add a guestbook entry",
);

Test the New Post

$mech->content_contains( "Scrappy Doo" );
$mech->content_contains( "Puppy power!" );

More Tests

• follow_link_ok - Follow a link
• html_lint_ok - Lint check your HTML
• text_contains - Without HTML
• page_links_ok - Check for broken links

Why?

• Why not unit testing instead?
• Integration testing
• User Model tests
• Make sure it works as the user would use it
• Limited test investment for good results
• Same tests, only automated

Coverage

• More code is exercised
• Fewer tests and less development time
• More time doing real work
• More confidence in the code

But...

• More difficult to track down test failures
• Not a replacement for unit tests
  • But only unit test your own code
• Nor a replacement for regression tests
  • Regression tests are non-optional

Questions

• Slides: http://preaction.github.com/Perl/PSGI-Testing.html
• Code: MyApp.pm, myapp.t

Slides are licensed under a CC-BY-SA 3.0 license.

Code is licensed under the Artistic License or GNU GPL v1.0 or later, at your discretion (the same terms as Perl 5 itself).